const grippers=2.
const lasttime=3.

time(0..lasttime).

location(B) :- block(B).
location(table).

% GENERATE 

{ move(B,L,T) : block(B) : location(L) } grippers :- time(T), T<lasttime.

% DEFINE 

% effect of moving a block 
on(B,L,T+1) :- move(B,L,T), block(B), location(L), time(T), T<lasttime.

% inertia

on(B,L,T+1) :- on(B,L,T), not on'(B,L,T+1), location(L), block(B), time(T), T<lasttime.

% uniqueness of location

on'(B,L1,T) :- on(B,L,T), L!=L1, block(B), location(L), location(L1), time(T).

% TEST 

% on' is the negation of on
:- on(B,L,T), on'(B,L,T),
   block(B), location(L), time(T).

% two blocks cannot be on top of the same block 
:- 2 { on(B1,B,T) : block(B1) },
   block(B), time(T).

% a block can't be moved unless it is clear 
:- move(B,L,T), on(B1,B,T),
   block(B), block(B1), location(L), time(T), T<lasttime.

% a block can't be moved onto a block that is being moved also
:- move(B,B1,T), move(B1,L,T),
   block(B), block(B1), location(L), time(T), T<lasttime.

block(1..6). 

% Initial state:     Goal: 
% 
%                      3   6 
%   1   3   5          2   5 
%   2   4   6          1   4 
% -------------      ---------

% DEFINE 

on(1,2,0).
on(2,table,0).
on(3,4,0).
on(4,table,0).
on(5,6,0).
on(6,table,0).

% TEST
:- not on(3,2,lasttime).
:- not on(2,1,lasttime).
:- not on(1,table,lasttime).
:- not on(6,5,lasttime).
:- not on(5,4,lasttime).
:- not on(4,table,lasttime).

% DISPLAY 

hide on(B,L,T).
hide on'(B,L,T).
hide block(B).
hide time(T).
hide location(L).